Initial commit

src/launcher/CMakeLists.txt

@@ -0,0 +1,103 @@
+
+find_package(Qt6 COMPONENTS Concurrent Network Widgets REQUIRED)
+
+set(CMAKE_AUTOUIC_SEARCH_PATHS forms)
+set(CMAKE_INCLUDE_CURRENT_DIR ON)
+
+file(GLOB launcher_src
+	"include/*.h"
+	"src/*.cpp"
+)
+
+file(GLOB launcher_forms
+	"forms/*.ui"
+)
+
+add_executable(launcher WIN32
+	${launcher_src}
+	${launcher_forms}
+)
+
+
+target_link_libraries(launcher Qt6::Concurrent Qt6::Network Qt6::Widgets)
+if(WIN32)
+target_link_libraries(launcher setupapi)
+endif()
+if (CLANG AND NOT KYTY_CLANG_CL)
+target_link_libraries(launcher pthread)
+endif()
+target_include_directories(launcher PRIVATE "${CMAKE_CURRENT_SOURCE_DIR}/include" "${CMAKE_CURRENT_SOURCE_DIR}/src")
+set_target_properties(launcher PROPERTIES AUTOUIC ON AUTOMOC ON AUTORCC ON)
+
+if(WIN32 AND NOT KYTY_CLANG_CL)
+	set_target_properties(launcher PROPERTIES LINK_FLAGS "${KYTY_LD_OPTIONS}")
+endif()
+
+add_dependencies(launcher KytyGitVersion)  
+add_dependencies(launcher kyty_emulator)
+
+if(KYTY_CLANG_CL)
+	add_custom_command(TARGET launcher POST_BUILD
+		COMMAND ${CMAKE_COMMAND} -E copy_if_different $<TARGET_PDB_FILE:kyty_emulator> $<TARGET_FILE_DIR:launcher>/$<TARGET_PDB_FILE_NAME:kyty_emulator>
+		COMMAND ${CMAKE_COMMAND} -E copy_if_different $<TARGET_FILE_DIR:kyty_emulator>/${KYTY_EMULATOR_MAP_NAME} $<TARGET_FILE_DIR:launcher>/${KYTY_EMULATOR_MAP_NAME}
+		COMMAND ${CMAKE_COMMAND} -E copy_if_different "${KYTY_THIRD_PARTY_DIR}/winpthread/bin/libwinpthread-1.dll" $<TARGET_FILE_DIR:launcher>/libwinpthread-1.dll
+	)
+endif()
+
+if(WIN32)
+    find_program(QT_WINDEPLOYQT NAMES windeployqt PATHS "${Qt6_DIR}/../../../bin")
+    if(NOT QT_WINDEPLOYQT)
+    	message(FATAL_ERROR "Could not find windeployqt")
+    endif()
+	add_custom_command(TARGET launcher POST_BUILD
+		COMMAND ${QT_WINDEPLOYQT} $<TARGET_FILE:launcher>
+			--no-compiler-runtime
+			--no-system-d3d-compiler
+			--no-system-dxc-compiler
+			--no-opengl-sw
+			--no-translations
+		COMMENT "Deploying Qt runtime and TLS plugins"
+		VERBATIM
+	)
+endif()
+
+set(launcher_name "launcher")
+
+set_target_properties(launcher PROPERTIES OUTPUT_NAME ${launcher_name})
+
+install(TARGETS launcher DESTINATION .)
+
+if(WIN32)
+    install(CODE "
+    		execute_process(
+    			COMMAND ${QT_WINDEPLOYQT} \"\${CMAKE_INSTALL_PREFIX}/${launcher_name}.exe\"
+				--no-compiler-runtime
+				--no-system-d3d-compiler
+				--no-system-dxc-compiler
+				--no-opengl-sw
+				--no-translations
+    		)
+    ")
+endif()
+
+
+set(tidy_dirs "${CMAKE_SOURCE_DIR}/launcher/include") 
+set(iwyu_maps "${CMAKE_SOURCE_DIR}/launcher/utils/qt6_16.imp")
+
+get_property(inc_headers TARGET launcher PROPERTY INCLUDE_DIRECTORIES)
+
+list(APPEND inc_headers
+	${CMAKE_SOURCE_DIR}/launcher
+	${CMAKE_BINARY_DIR}/launcher/launcher_autogen/include
+	${Qt6Widgets_INCLUDE_DIRS}
+	${Qt6Core_INCLUDE_DIRS}
+	${Qt6Gui_INCLUDE_DIRS}
+	#${Qt6_DIR}/../../../include
+	#${Qt6_DIR}/../../../include/QtWidgets
+	#${Qt6_DIR}/../../../include/QtCore
+	#${Qt6_DIR}/../../../include/QtGui
+)
+
+include_what_you_use_with_mappings(launcher "${inc_headers}" "${iwyu_maps}")
+
+clang_tidy_check(launcher "" "${tidy_dirs}" "${inc_headers}")